XP计划任务 怎样设定 定时开机??
发布网友
发布时间：2022-04-24 14:35
共3个回答
热心网友
时间：2023-10-16 16:04
设置步骤如下：
1、电脑开机之后根据屏幕上的提示信息按“Del”键进入主板BIOS设置画面，与定时开机有关的设置功能一般放在“Power Management Setup”（电源管理设置）选项下
2、在BIOS中有一项“RTC Alarm Poweron”的选项，应设成“Enabled”(启用)。之后用户可以具体设好定时开机的日期、小时、分钟、秒钟
3、为了保证电脑准确无误地实现定时自动开机的功能，用户还要先检查一下主板BIOS中的系统时间是否与现实时间相同。
4、最后一步要记得将主板BIOS中的设置修改结果进行保存，即可在预设的时间定时开机。某些主板上还能够设成每日同一时间从BIOS自动开机，方法是将“RTC Alarm Date”一项改为“Every Day”。
热心网友
时间：2023-10-16 16:05
自动定时开机的实现
首先在启动计算机时，按“Delete”键进入BIOS界面。在BIOS设置主界面中选择“Power Management Setup”菜单，进入电源管理窗口。默认情况下，“Automatic Power Up(定时开机，有些机器选项为Resume By Alarm)”选项是关闭的，将光标移到该项，用PageUp或PageDown翻页键将“Disabled”改为“Enabled”，而后在“Date (of Month) Alarm”和“
Time (hh:mm:ss) Alarm”中分别设定开机的日期和时间。
如果“Date”设为0，则默认为每天定时开机。设置好后按“ESC”键回到BIOS设置主界面，点击“Save Exit Setup”，按“Y”键保存CMOS设置退出，接着机器会重新启动，这时便大功告成了。当然，值得注意的是定时开机需要您的主板支持才行，不过现在大多数主板都有这项功能。另外，不同的主板在设置上会不尽相同，不过都大同小异。
定时关机的实现
单击“开始”按钮，在“开始”菜单中选择“程序”选项，在“程序”中选择“附件”，再在“附件”中选择“系统工具”，在“系统工具”中选择“计划任务”命令，这时就打开了“计划任务”窗口，在该窗口中，点击“添加已计划的任务”进入“计划任务”向导。按照提示点击“下一步”后，再点击“浏览”按钮，找到“C:WindowsRundll32.exe”打开，然后根据自己的需求设置任务执行的方式，如每天或每周。最后设置好这个任务开始的时间和开始的日期，点击“完成”按钮就会在计划任务窗口出现“Rundll32”这个计划任务名。
这个计划任务还需要进行属性的修改设置，在计划任务窗口，双击“Rundll32”打开属性窗口，在“运行”栏中把原有的内容修改为:C:WINDOWSRundll32.exe user.exe,exitwindows。注意user.exe和exitwindows之间的“，”必须为英文半角，且其前后不能有“空格”。
这样，定时开机、关机就全部设置完成。
复制以下内容保存为一个.bat的文件。然后你就可以尽情发挥了。
@ECHO off
TITLE 自动命令执行。
:start
CLS
COLOR 1f
rem 使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=41 LINES=18
rem MODE语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%点%tm2%分%tm3%秒
ECHO =========================================
ECHO 请选择要进行的操作，然后按回车
ECHO ———————————————
ECHO.
ECHO 1. 定时关机
ECHO 2. 倒计时关机(单位:秒)
ECHO 3. 删除定时关机任务
ECHO 4. 查看任务状态
ECHO 5. 刷新当前时间
ECHO 6. 重新启动
ECHO 7. 锁定计算机
ECHO 8. 注销
ECHO 9. 退出
ECHO.
:cho
SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入
ECHO.
GOTO cho
:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour
:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes
:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no
:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start
:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO ————————
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入(秒):
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime
:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start
:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start
:restart
shutdown -r -t 0
:lock
rundll32.exe user32.dll,LockWorkStation
goto start
:logoff
logoff
:end
exit
热心网友
时间：2023-10-16 16:05
靠,太麻烦了,,比如XP系统,自动关机是,在运行里输入
shutdown -s -t 时间,
如果想要60秒就关机
shutdown -s -t 60 取消shutdown -a
